Blog: Mouse Trap replacement seesaw: mousetrap-seesaw.scad

length = 4.25;
width = 0.96;
bar_slot_diameter = 0.190;
slot_to_surface = 0.165;
slab_thickness = 0.132;
slab_end_thickness = 0.190;
slab_end_depth = 0.077;
slot_support_height = 0.425;
slot_support_length = 2.065;
slot_support_face = 0.450;
slot_support_width = 0.547;
slot_support_side_thickness = 1/16;
slot_support_inner_width = slot_support_width - 2*slot_support_side_thickness;

cut_margin = 0.0001;

module seesaw() {
    difference() {
        union() {
            // main slab
            translate([-length/2, 0, 0]) {
                cube([length, width, slab_thickness]);
            }
            // slot support
            hull() {
                translate([-slot_support_face/2, (width-slot_support_width)/2, 0]) {
                    cube([slot_support_face, slot_support_width, slot_support_height]);
                }
                translate([-slot_support_length/2, (width-slot_support_width)/2, 0]) {
                    cube([slot_support_length, slot_support_width, slab_thickness]);
                }
            }
            // ends
            translate([length/2-slab_end_depth, 0, 0]) {
                cube([slab_end_depth , width, slab_end_thickness]);
            }
            translate([-length/2, 0, 0]) {
                cube([slab_end_depth , width, slab_end_thickness]);
            }
        }
        union() {
            // turn the support into a pair of walls
            translate([-slot_support_length/2, (width-slot_support_inner_width)/2, slab_thickness]) {
                cube([slot_support_length, slot_support_inner_width, slot_support_height-slab_thickness+cut_margin]);
            }
            // straight part of the slot the bar passses by
            translate([-bar_slot_diameter/2, -cut_margin, slot_support_height + slot_to_surface + bar_slot_diameter/2]) {
                rotate([-90, 0, 0]) {
                    cube([bar_slot_diameter, slot_support_height, width+2*cut_margin]);
                }
            }
            // round part of the slot that rests on the bar
            translate([0, 0, slot_to_surface + bar_slot_diameter/2]) {
                rotate([-90, 0, 0]) {
                    cylinder(d=bar_slot_diameter, h=width+2*cut_margin, $fn=64);
                }
            }
        }
    }
}

seesaw();